aboutsummaryrefslogtreecommitdiffstatshomepage
path: root/gajim
diff options
context:
space:
mode:
Diffstat (limited to 'gajim')
-rw-r--r--gajim/gajim/PKGBUILD49
-rw-r--r--gajim/python-nbxmpp/PKGBUILD28
2 files changed, 77 insertions, 0 deletions
diff --git a/gajim/gajim/PKGBUILD b/gajim/gajim/PKGBUILD
new file mode 100644
index 0000000..3a0a31f
--- /dev/null
+++ b/gajim/gajim/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Eric Bélanger <eric@archlinux.org>
+
+pkgname=gajim
+pkgver=1.2.1
+pkgrel=1
+pkgdesc='Full featured and easy to use XMPP (Jabber) client'
+url='https://www.gajim.org/'
+arch=('any')
+license=('GPL3')
+depends=('gtk3' 'python-cairo' 'python-gobject' 'python-keyring' 'python-nbxmpp'
+ 'python-pyasn1' 'python-pyopenssl' 'python-precis_i18n' 'python-cssutils'
+ 'python-distro' 'hicolor-icon-theme' 'python-css-parser')
+optdepends=('alsa-utils: play notification sounds'
+ 'python-dbus: for gajim-remote and zeroconf support'
+ 'avahi: serverless chatting with autodetected clients in a local network'
+ 'farstream: start audio and video chat'
+ 'gst-plugins-good: for video/voice support'
+ 'gst-plugins-bad: for video/voice support'
+ 'gst-plugins-ugly: for video/voice support'
+ 'gst-libav: for video/voice support'
+ 'gst-python: for video/voice support'
+ 'gspell: for spell checking support'
+ 'notification-daemon: for desktop notifications'
+ 'geoclue2: share current location'
+ 'gnome-keyring: store passwords encrypted in GNOME Keyring'
+ 'kded: store passwords encrypted in KSecretService'
+ 'gupnp-igd: request your router to forward port for file transfer'
+ 'libxss: measure idle time, in order to set auto status'
+ 'python-crypto: encrypting chat messages'
+ 'python-docutils: generate XHTML output from RST code'
+ 'python-gnupg: encrypting chat messages with OpenPGP'
+ 'python-pillow: support of WebP avatars'
+ 'python-axolotl: OMEMO support'
+ 'python-qrcode: generate QR codes for OMEMO keys')
+source=(https://dev.gajim.org/gajim/gajim/-/archive/gajim-${pkgver}/gajim-gajim-${pkgver}.tar.bz2)
+sha512sums=('52ff2daa478e31aac153fbff9fe94f6cec21d4666fbeb5dfbf3125d712f9fa7f3a4858b4e11ee9b4a0a6c517e6025d017c6dd7df2a68828c9d230a351598a47f')
+
+build() {
+ cd ${pkgname}-${pkgname}-${pkgver}
+ python setup.py build
+}
+
+package() {
+ cd ${pkgname}-${pkgname}-${pkgver}
+ python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+}
+
+# vim: ts=2 sw=2 et:
diff --git a/gajim/python-nbxmpp/PKGBUILD b/gajim/python-nbxmpp/PKGBUILD
new file mode 100644
index 0000000..49af135
--- /dev/null
+++ b/gajim/python-nbxmpp/PKGBUILD
@@ -0,0 +1,28 @@
+# Maintainer:
+# Contributor: Eric Bélanger <eric@archlinux.org>
+
+pkgname=python-nbxmpp
+pkgdesc="A Python library to use Jabber/XMPP networks in a non-blocking way"
+pkgver=1.0.1
+pkgrel=1
+arch=(any)
+url="https://dev.gajim.org/gajim/python-nbxmpp/"
+license=(GPL3)
+depends=(python)
+makedepends=(python-setuptools)
+source=($pkgname-$pkgver.tar.gz::https://dev.gajim.org/gajim/python-nbxmpp/repository/nbxmpp-$pkgver/archive.tar.gz)
+sha256sums=('f15de5c908e5e6c62582614023beb3c218d55cb3170c3dd24470b49351065795')
+
+prepare() {
+ mv $pkgname-nbxmpp-* $pkgname-$pkgver
+}
+
+build() {
+ cd $pkgname-$pkgver
+ python setup.py build
+}
+
+package() {
+ cd $pkgname-$pkgver
+ python setup.py install --root="$pkgdir"
+}